ارتباط با wep

[hesam.time]

ارتباط با WEP
این مثال به شما چگونگی اتصال به یک شبکه رمزگذاری شده WEP ،b/g802.11 را با Arduino WiFi shield نشان می دهد. مانیتور سریال آردینو شما ، اطلاعات مربوط به اتصال را به محض آنکه متصل می شود، فراهم خواهد آورد.
سخت افزار موردنیاز
Arduino WiFi Shield
شیلد سازگار با برد آردینو
مدار
شیلد WiFi از پین های 10 ، 11 ، 12، و 13 برای ارتباط SPI به ماژول HDG104 استفاده می کند. پین 4 دیجیتال ، برای کنترل پین انتخاب slave روی SD کارت استفاده می شود. برای این مثال شما باید به شبکه وایرلس 802.11b/g که به اینترنت متصل است؛ دسترسی داشته باشید.
شما احتیاج خواهید داشت تنظیمات شبکه در طرح را مطابقSSID شبکه خاص خود تغییر دهید.
پسورد در شبکه WEP ، رشته های هگزادسیمال به عنوان کلید شناخته شده هستند. یک شبکه WEP می تواند 4 کلید متفاوت داشته باشد؛ به هر کلید
یک مقدار”Key Index” اختصاص داده شده است. برای شبکه های رمزگذاری شده ی WEP ،شما به SSID ، کلید ، و شماره کلید احتیاج دارید.

#include <WiFi.h>

char ssid[] = "yourNetwork";                     // شبکه شما SSID (اسم)
char key[] = "D0D0DEADF00DABBADEAFBEADED";       // کلید (رمز) شبکه شما
int keyIndex = 0;                                // فهرست شماره کلید شبکه شما
int status = WL_IDLE_STATUS;                     // وضعیت رادیو وای فای

void setup() {
  // مقداردهی اولیه سریال :
  Serial.begin(9600);

  // تلاش برای اتصال به یک شبکه باز :
  Serial.print("Attempting to connect to WEP network: ");
  Serial.println(ssid);
  status = WiFi.begin(ssid, keyIndex, key);

  // اگر شما متصل نشدید ،اینجا متوقف می شود :
  if ( status != WL_CONNECTED) { 
    Serial.println("Couldn't get a wifi connection");
    while(true);
  } 
  // اگر شما متصل هستید :
  else {
    Serial.print("You're connected to the network");
    printCurrentNet();
    printWifiData();
  }
}

void loop() {
  // check the network connection once every 10 seconds:
  delay(10000);
  printCurrentNet();
}

void printWifiData() {
  // چاپ آدرس آی پی شیلد وای فای شما:
  IPAddress ip = WiFi.localIP();
    Serial.print("IP Address: ");
  Serial.println(ip);
  Serial.println(ip);

  // چاپ آدرس مک شما:
  byte mac[6];  
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  Serial.print(mac[5],HEX);
  Serial.print(":");
  Serial.print(mac[4],HEX);
  Serial.print(":");
  Serial.print(mac[3],HEX);
  Serial.print(":");
  Serial.print(mac[2],HEX);
  Serial.print(":");
  Serial.print(mac[1],HEX);
  Serial.print(":");
  Serial.println(mac[0],HEX);
}

void printCurrentNet() {
  // شبکه که شما متصلید SSID چاپ :
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // چاپ آدرس مک روتری که شما متصلید:
  byte bssid[6];
  WiFi.BSSID(bssid);    
  Serial.print("BSSID: ");
  Serial.print(bssid[5],HEX);
  Serial.print(":");
  Serial.print(bssid[4],HEX);
  Serial.print(":");
  Serial.print(bssid[3],HEX);
  Serial.print(":");
  Serial.print(bssid[2],HEX);
  Serial.print(":");
  Serial.print(bssid[1],HEX);
  Serial.print(":");
  Serial.println(bssid[0],HEX);

  // چاپ قدرت سیگنال دریافت شده:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // چاپ نوع رمزنگاری:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption,HEX);
  Serial.println();
}

لینک سایت:Arduino - ConnectWithWEP