صفحه 1 از 2 12 آخرینآخرین
نمایش نتایج: از 1 به 10 از 17
Like Tree3 لایک

موضوع: ماژول فرستنده و گيرنده راديويي سريال mx-fs-03v , mx-05v 315MHZ

  1. #1
    max
    max آنلاین نیست.
    Member
    تاریخ عضویت
    Jul 2013
    محل سکونت
    iran-shiraz
    نوشته ها
    70

    ماژول فرستنده و گيرنده راديويي سريال mx-fs-03v , mx-05v 315MHZ

    يكي از پراستفاده ترين مدارهاي الكترونيكي ، مدارهاي كنترل از راه دور ميباشد. روز به روز بر تعداد تجهيزاتي كه انتقال اطلاعات و كنترل را بصورت wireless انجام ميدهند افزوده ميشود . ماژولهاي فرستنده و گيرنده mx-fs-03v و mx-05v يكي از ساده ترين ماژولهاي انتقال اطلاعات به شمار ميروند . انتقال اطلاعات در اين ماژولها تنها از طريق 1 پين صورت ميپذيرد.و در مواردي كه از نظر تعداد پايه هاي آردوينو با محدوديت مواجه هستيم ، اين ويژگي ميتواند بسيار مفيد باشد.
    rf_mx-fs-03v-mx-05v.jpg
    مشخصات فرستنده mx-fs-03v:
    برد فرستنده : 20 تا 200 متر
    ولتاژ تغذيه : 3.5 تا 12 ولت
    سرعت انتقال اطلاعات : 4kB/s
    توان فرستنده: 10mw
    فركانس مدولاتور:315Mhz
    rf-tx-sch.jpg
    مشخصات گيرندهmx-05v:
    ولتاژ تغذيه : 5 ولت
    حساسيت گيرنده:105db-
    فركانس اسيلاتور:315Mhz
    rf-rx-sch.jpg
    mx-fs.gif
    كاربردها:
    سیستم های امنیتی بی سیم
    دزدگیر
    درب باز كن
    کنترل از راه دور
    فرستنده وگیرنده اطلاعات
    ارسال اطلاعات سنسور و...

    در برنامه زير مقدار آنالوگ خوانده شده از ورودي A0 از طريق ماژول فرستنده ارسال ميشود.
    کد:
    /*
     # 
     # Example code for MX-FS-03V RF TRANSMITTER 
     # Company    : AftabRayaneh
     # Website    : http://shop.aftabrayaneh.com
     # Editor     : mohammad omidvar - max
     # Date       : 19.10.2013
     # Version    : 1.0
     */
     /*
    
    Tx MODULE CONNECTIONS:
    
    PIN  DESCRIPTION      ARDUINO PIN
    1    GND              GND
    2    VCC (3.5-12V)    VCC
    3    TX DATA          D2
    
    */
    
    
    /*Include the VirtualWire library */
    #include <VirtualWire.h>
    
    /* Digital IO pin that will be used for sending data to the transmitter */
    const int TX_DIO_Pin = 2;
    
    
    void setup()
    {
      pinMode(13, OUTPUT);
      /* Initialises the DIO pin used to send data to the Tx module */
      vw_set_tx_pin(TX_DIO_Pin);
      /* Set the transmit logic level (LOW = transmit for this 
         version of module)*/ 
      vw_set_ptt_inverted(true); 
      
      /* Transmit at 2000 bits per second */
      vw_setup(2000);    // Bits per sec
    }
    
    /* Main program */
    void loop()
    {
      /* Temporarily holds the value read from analogue input A0 */
      unsigned int Data;
      /* The transmit buffer that will hold the data to be 
         transmitted. */
      byte TxBuffer[2];
      
      /* Read the analogue input A0... */
      Data = analogRead(A0);
      /* ...and store it as high and low bytes in the transmit 
         buffer */
      TxBuffer[0] = Data >> 8;
      TxBuffer[1] = Data;
      
      /* Turn on the LED on pin 13 to indicate that we are about 
        to transmit data */
      digitalWrite(13, HIGH); 
      /* Send the data (2 bytes) */
      vw_send((byte *)TxBuffer, 2);
      /* Wait until the data has been sent */
      vw_wait_tx(); 
      
      /* Turn off the LED on pin 13 to indicate that we have 
         now sent the data */
      digitalWrite(13, LOW); 
      
      /* Do nothing for a second. Lower this delay to send 
         data quicker */
      delay(1000);
    }
    برنامه زير عدد ارسال شده را توسط ماژول گيرنده دريافت كرده و از طريق serial monitor نمايش ميدهد.
    کد:
    /*
     # 
     # Example code for MX-05V RF RECEIVER
     # Company    : AftabRayaneh
     # Website    : http://shop.aftabrayaneh.com
     # Editor     : mohammad omidvar - max
     # Date       : 19.10.2013
     # Version    : 1.0
     */
    /*
    Rx MODULE CONNECTIONS:
    
    PIN  DESCRIPTION      ARDUINO PIN
    1    GND              GND
    2    RX DATA          D2
    3    RX DATA          N/A
    4    VCC (5V)         VCC
    
    */
    
    
    /*Include the VirtualWire library */
    #include <VirtualWire.h>
    
    /* Digital IO pin that will be used for receiving data from the receiver */
    const int RX_DIO_Pin = 2;
    
    void setup()
    {
        pinMode(13, OUTPUT);
        Serial.begin(9600);
    
        /* Initialises the DIO pin used to receive data from the Rx module */
        vw_set_rx_pin(RX_DIO_Pin);
        
        /* Receive at 2000 bits per second */
        vw_setup(2000);
        
        /* Enable the receiver */
        vw_rx_start(); 
    }
    
    /* Main program */
    void loop()
    {
      /* Set the receive buffer size to 2 bytes */
      uint8_t Buffer_Size = 2;
      
      /* Holds the recived data */
      unsigned int Data;
      
      /* The receive buffer */
      uint8_t RxBuffer[Buffer_Size];
    
        /* Has a message been received? */
        if (vw_get_message(RxBuffer, &Buffer_Size)) // Non-blocking
        {
            /* If so, then turn on the LED connected to DIO 13 
               to indicate this */
            digitalWrite(13, HIGH); 
       
            /* Store the received high and low byte data */
            Data = RxBuffer[0] << 8 | RxBuffer[1];
    
            /* Output this data to the UART */
       Serial.print("Analogue pin A0: ");
            Serial.println(Data);
       
            /* Turn off the LED on pin 13 to indicate that the 
               data has now been received */
            digitalWrite(13, LOW);
        }
    }

    جهت سفارش این کالا، به این بخش در فروشگاه آفتاب رایانه مراجعه نمایید.
    فایل های پیوست شده فایل های پیوست شده
    ویرایش توسط max : 10-20-2013 در ساعت 11:41 AM

  2. #2
    Junior Member
    تاریخ عضویت
    Jul 2014
    نوشته ها
    6
    سلام
    من پروژه فوق را بستم...
    ماژول فرستنده اقدام به ارسال داده میکند (یعنی ال ای دی پایه 13 چشمک میزند)
    اما ماژول گیرنده چشمک نمیزند و در سریال مانیتور هیچ متنی نمایش داده نمی شود.!
    در ماژول گیرنده یکبار دو پایه مربوط به دیتا را به هم وصل کردم و بار دیگر فقط از یک پیش استفاده کردم اما در هر دو صورت هیچ تغییری حاصل نشد و همچنان گیرنده عکس العملی از خود نشان نمی داد.
    لطفا راهنمایی کنید.
    با تشکر

  3. #3
    Junior Member
    تاریخ عضویت
    Jul 2015
    نوشته ها
    1

    فرستنده گیرنده

    با سلام و خسته نباشید
    سوالم اینه ک این ماژول ها از لحاظ نویز پذیری چ جورین؟؟
    ینی میشه 3 جفت از این گیرنده فرستنده رو در کنار هم کار کنن؟
    با تشکر از پاسختون

  4. #4
    Junior Member
    تاریخ عضویت
    Jul 2015
    نوشته ها
    28
    نقل قول نوشته اصلی توسط محمد علی نمایش پست ها
    با سلام و خسته نباشید
    سوالم اینه ک این ماژول ها از لحاظ نویز پذیری چ جورین؟؟
    ینی میشه 3 جفت از این گیرنده فرستنده رو در کنار هم کار کنن؟
    با تشکر از پاسختون
    این ماژولها برای فرستادن دیتا باید کد کذاری بشن وگرنه باهم تداخل میکنند
    لایک کردن

  5. #5
    Junior Member
    تاریخ عضویت
    Feb 2015
    نوشته ها
    1
    سلام آیا نسخه 1.6.7 آردینو پشتیبانی میکنه
    هرکاری کردم کمپایل ها رو بخونه نخوند میشه راهنمایی کنید

  6. #6
    مدیر گروه
    تاریخ عضویت
    Nov 2013
    محل سکونت
    ایران
    نوشته ها
    4,024
    نقل قول نوشته اصلی توسط armin2012 نمایش پست ها
    سلام آیا نسخه 1.6.7 آردینو پشتیبانی میکنه
    هرکاری کردم کمپایل ها رو بخونه نخوند میشه راهنمایی کنید

    دوست عزیز متاسفانه من متوجه منظور شما نمیشم
    کدوم کد رو کامپایل کردید که ارور داده؟

  7. #7
    Member
    تاریخ عضویت
    Nov 2013
    نوشته ها
    53
    نقل قول نوشته اصلی توسط armin2012 نمایش پست ها
    سلام آیا نسخه 1.6.7 آردینو پشتیبانی میکنه
    هرکاری کردم کمپایل ها رو بخونه نخوند میشه راهنمایی کنید
    تعریف بعضی از مقادیر ثابت در نسخه های جدید آردینو تغیر کرده و بعضی کتابخانه های قدیمی در آردوینو جدید کامپایل نمیشن و ارور میدن
    یا باید کتاب خونه رو ادیت کنید و درستش کنید و یا از محیط آردینو قدیمی تر استفاده کنید

  8. #8
    مدیر گروه
    تاریخ عضویت
    Nov 2013
    محل سکونت
    ایران
    نوشته ها
    4,024
    نقل قول نوشته اصلی توسط alt_f4 نمایش پست ها
    تعریف بعضی از مقادیر ثابت در نسخه های جدید آردینو تغیر کرده و بعضی کتابخانه های قدیمی در آردوینو جدید کامپایل نمیشن و ارور میدن
    یا باید کتاب خونه رو ادیت کنید و درستش کنید و یا از محیط آردینو قدیمی تر استفاده کنید

    آخه VirtualWire نباید مشکلی داشته باشه .
    فکر می کنم تو مراحل add کردن اشتباه کردن.

  9. #9
    Junior Member
    تاریخ عضویت
    Dec 2015
    نوشته ها
    10
    با سلام
    من از ای برنامه استفاده کردم و جواب داد ولی وقتی که کتابخونه servo و vitualwire رو کنار هم توی یه برنامه مینویسم error میده ، اگه میشه راهنمایی کنید که مشکلم کجاس .

  10. #10
    مدیر گروه
    تاریخ عضویت
    Nov 2013
    محل سکونت
    ایران
    نوشته ها
    4,024
    نقل قول نوشته اصلی توسط pooriab نمایش پست ها
    با سلام
    من از ای برنامه استفاده کردم و جواب داد ولی وقتی که کتابخونه servo و vitualwire رو کنار هم توی یه برنامه مینویسم error میده ، اگه میشه راهنمایی کنید که مشکلم کجاس .
    اول تک تک کتابخونه ها رو اضافه کنید ببینید با تک تک کتابخونه ها مشکل داره ؟
    می تونید کدتون رو اینجا هم بزارید ببینیم چشه

صفحه 1 از 2 12 آخرینآخرین

مجوز های ارسال و ویرایش

  • شما نمیتوانید موضوع جدیدی ارسال کنید
  • شما امکان ارسال پاسخ را ندارید
  • شما نمیتوانید فایل پیوست کنید.
  • شما نمیتوانید پست های خود را ویرایش کنید
  •  

SEO by vBSEO