ماژول تشخیص اثر انگشت Fingerprint Recognition

[hesam.time]

ماژول تشخیص اثر انگشت
ماژول اسکنر اثر انگشت دارای یک سنسور اثر انگشت است که امکان تشخیص و شناسایی اثر انگشت و افزودن تاییدیه بسیار ساده را برای کاربر فراهم می کند. این ماژول دارای چیپ DSP قدرتمند AS601 است که وظیفه رندر کردن تصویر ، محاسبه و قابلیت پیدا کردن و جستجو را برعهده دارد.شما همچنین با استفاده از حافظه FLASH داخلی این ماژول می توانید تا 162 اثر انگشت را مستقیما ثبت و ذخیره کنید. این ماژول دارای یک LED قرمز داخل لنز آن است که به هنگام گرفتن عکس روشن شده و شما را از وضعیت کارکرد آن آگاه می سازد. استفاده از این ماژول آسان بوده بهترین وسیله ایست که می توانید برای اسکن از اثر انگشت داشته باشید. این ماژول با آردوینو کاملا سازگار بوده و براحتی توسط آن قابل راه اندازی می باشد.



مشخصات
ولتاژ تغذیه: 3.6~6.0 ولت
ماکزیمم جریان کاری: 120mA
مدت زمان تصویر برداری از اثر انگشت: 1.0S
مد Match : مد مقایسه 1:1
مد جستجو: 1:N
ظرفیت ذخیره سازی: 162 نمونه
نرخ پذیرش نادرست: 0.001% (سطح امنیتی 3)
نرخ نپذیرفتن نادرست: 1.0% (سطح امنیتی 3)
نرخ baud:
9600, 19200, 28800, 38400, 57600bps (پیش فرض 57600)
نوع ارتباط : سریال TTL
دمای کاری: 20- ~ 50+ درجه سانتی گراد

مثال
در این مثال با اتصال ماژول تشخیص اثر انگشت به آردوینو می توانید میزان اطمینان از مطابقت اثر انگشت را بصورت اعداد 1 تا 255 در Serial Monitor مشاهده کنید.

#include <Adafruit_Fingerprint.h>
#if ARDUINO >= 100
 #include <SoftwareSerial.h>
#else
 #include <NewSoftSerial.h>
#endif

int getFingerprintIDez();

// pin #2 is IN from sensor (GREEN wire)
// pin #3 is OUT from arduino  (WHITE wire)
#if ARDUINO >= 100
SoftwareSerial mySerial(2, 3);
#else
NewSoftSerial mySerial(2, 3);
#endif

Adafruit_Fingerprint finger = Adafruit_Fingerprint(&mySerial);

void setup()  
{
  Serial.begin(9600);
  Serial.println("fingertest");

  // set the data rate for the sensor serial port
  finger.begin(57600);
  
  if (finger.verifyPassword()) {
    Serial.println("Found fingerprint sensor!");
  } else {
    Serial.println("Did not find fingerprint sensor :(");
    while (1);
  }
  Serial.println("Waiting for valid finger...");
}

void loop()                     // run over and over again
{
  getFingerprintIDez();
}

uint8_t getFingerprintID() {
  uint8_t p = finger.getImage();
  switch (p) {
    case FINGERPRINT_OK:
      Serial.println("Image taken");
      break;
    case FINGERPRINT_NOFINGER:
      Serial.println("No finger detected");
      return p;
    case FINGERPRINT_PACKETRECIEVEERR:
      Serial.println("Communication error");
      return p;
    case FINGERPRINT_IMAGEFAIL:
      Serial.println("Imaging error");
      return p;
    default:
      Serial.println("Unknown error");
      return p;
  }

  // OK success!

  p = finger.image2Tz();
  switch (p) {
    case FINGERPRINT_OK:
      Serial.println("Image converted");
      break;
    case FINGERPRINT_IMAGEMESS:
      Serial.println("Image too messy");
      return p;
    case FINGERPRINT_PACKETRECIEVEERR:
      Serial.println("Communication error");
      return p;
    case FINGERPRINT_FEATUREFAIL:
      Serial.println("Could not find fingerprint features");
      return p;
    case FINGERPRINT_INVALIDIMAGE:
      Serial.println("Could not find fingerprint features");
      return p;
    default:
      Serial.println("Unknown error");
      return p;
  }
  
  // OK converted!
  p = finger.fingerFastSearch();
  if (p == FINGERPRINT_OK) {
    Serial.println("Found a print match!");
  } else if (p == FINGERPRINT_PACKETRECIEVEERR) {
    Serial.println("Communication error");
    return p;
  } else if (p == FINGERPRINT_NOTFOUND) {
    Serial.println("Did not find a match");
    return p;
  } else {
    Serial.println("Unknown error");
    return p;
  }   
  
  // found a match!
  Serial.print("Found ID #"); Serial.print(finger.fingerID); 
  Serial.print(" with confidence of "); Serial.println(finger.confidence); 
}

// returns -1 if failed, otherwise returns ID #
int getFingerprintIDez() {
  uint8_t p = finger.getImage();
  if (p != FINGERPRINT_OK)  return -1;

  p = finger.image2Tz();
  if (p != FINGERPRINT_OK)  return -1;

  p = finger.fingerFastSearch();
  if (p != FINGERPRINT_OK)  return -1;
  
  // found a match!
  Serial.print("Found ID #"); Serial.print(finger.fingerID); 
  Serial.print(" with confidence of "); Serial.println(finger.confidence);
  return finger.fingerID; 
}

مرجع:
Grove - Fingerprint Sensor - Wiki
Wiring for use with Arduino | Adafruit Optical Fingerprint Sensor | Adafruit Learning System

جهت سفارش این کالا، به این بخش در فروشگاه آفتاب رایانه مراجعه نمایید.