ماژول انتقال بیسیم اطلاعات +nrf24l01 ( فرکانس 2.4g ) + آنتن

**hasang3** · 06-17-2015, 05:17 PM

نوشته اصلی توسط aminta

فک کنم مشکل از کتابخونه ادد کردن شماست.
شما پوشه ی کتابخونه را توی my document کپی کنید و یکبار برنامه آردینو را ببندید و باز کنید خودش اتوماتیک میاد توی مثالها!
من الان مثال client کامپایل میکنم اروری نمیده!

سلام. ممنون. بله اشکال از همونجا بود. بازم تشکر

**hasang3** · 06-17-2015, 06:11 PM

سلام دوباره.
یک سوال دیگه برام پیش اومده دوستان. ممنون میشم کمک کنید.
کد زیر رو من برای گیرنده استفاده کردم:

کد:

/* YourDuinoStarter Example: nRF24L01 Receive Joystick values

 - WHAT IT DOES: Receives data from another transceiver with
   2 Analog values from a Joystick or 2 Potentiometers
   Displays received values on Serial Monitor
 - SEE the comments after "//" on each line below
 - CONNECTIONS: nRF24L01 Modules See:
 http://arduino-info.wikispaces.com/Nrf24L01-2.4GHz-HowTo
   1 - GND
   2 - VCC 3.3V !!! NOT 5V
   3 - CE to Arduino pin 9
   4 - CSN to Arduino pin 10
   5 - SCK to Arduino pin 13
   6 - MOSI to Arduino pin 11
   7 - MISO to Arduino pin 12
   8 - UNUSED
   
 - V1.00 11/26/13
   Based on examples at http://www.bajdi.com/
   Questions: terry@yourduino.com */

/*-----( Import needed libraries )-----*/
#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
/*-----( Declare Constants and Pin Numbers )-----*/
#define CE_PIN   9
#define CSN_PIN 10

// NOTE: the "LL" at the end of the constant is "LongLong" type
const uint64_t pipe = 0xE8E8F0F0E1LL; // Define the transmit pipe


/*-----( Declare objects )-----*/
RF24 radio(CE_PIN, CSN_PIN); // Create a Radio
/*-----( Declare Variables )-----*/
int joystick[2];  // 2 element array holding Joystick readings

void setup()   /****** SETUP: RUNS ONCE ******/
{
  Serial.begin(9600);
  delay(1000);
  Serial.println("Nrf24L01 Receiver Starting");
  radio.begin();
  radio.openReadingPipe(1,pipe);
  radio.startListening();;
}//--(end setup )---


void loop()   /****** LOOP: RUNS CONSTANTLY ******/
{
  if ( radio.available() )
  {
    // Read the data payload until we've received everything
    bool done = false;
    while (!done)
    {
      // Fetch the data payload
      done = radio.read( joystick, sizeof(joystick) );
      Serial.print("X = "); 
      Serial.print(joystick[0]);
      Serial.print(" Y = ");      
      Serial.println(joystick[1]);
    }
  }
  else
  {    
      Serial.println("No radio available");
  }

}//--(end main loop )---

/*-----( Declare User-written Functions )-----*/

//NONE
//*********( THE END )***********

موقع کامپایل کردن به کد زیر گیر میده:

کد:

done = radio.read( joystick, sizeof(joystick) );

خطایی که میده اینه:

کد:


reseiver.ino: In function 'void loop()':
reseiver.ino:59:12: error: void value not ignored as it ought to be
Error compiling.

من تو آموزشایی که تو اینترنت گذاشتن نگاه کردم دیدم همین کد رو بدون مشکل استفاده کردن و همچین خطایی نداشتن. اگر چیزی به ذهنتون میرسه خوشحال میشم بدونم. بازم ممنون

**mohammad_robotic** · 06-28-2015, 07:24 AM

من یک جفت از این ماژول ها رو راه اندازی کردم ولی مشکل این جاست که ارتباط یک طرفه است. یعنی مثلا برای من فقط میتونم روی com6 بنویسم و روی com8 بخونم ولی وقتی روی com8 مینویسم چیزی رو com6 نشون نمیده.
کسی نظری یا راه حلی سراغ داره؟؟/

**ss13** · 06-28-2015, 05:48 PM

سلام دوستان
من میخوام با ماژول NRF یک فرستنده گیرنده راه بندازم که هنگامی که در برد اول پایه ی 14 یک شد در برد دوم این پایه یک بشه
من از دو تا آردوینو 2560 و دو تاماژول NRF24L01 استفاده کردم
برنامه برد اول که فرستنده است رو این طور نوشتم:
#include <SPI.h>
#include <Mirf.h>
#include <NRF24L01.h>
#include <MirfHardwarespiDriver.h>
int led = 14;
int i;
void setup() {
pinMode(led, INPUT);
Serial.begin(9600);
Mirf.spi=&MirfHardwareSpi;
Mirf.init();
Mirf.setRADDR((byte*)"clie2");
Mirf.setTADDR((byte*)"clie1");
Mirf.payload=sizeof(unsigned long);
Mirf.config();
byte rf_setup=0;
Mirf.readRegister(RF_SETUP , &rf_setup,sizeof(rf_setup));
if(rf_setup!=0)
Serial.println("beginning");
else
{Serial.println("no signal");
while(rf_setup=0);}
delay(1000);
}

void loop() {
pinMode(led, INPUT);
if(digitalRead(led)==HIGH)
{
i=0;
Mirf.send((byte*)&i);
}
}
برنامه برد دوم که گیرنده هست رو این طور نوشتم:
#include <SPI.h>
#include <Mirf.h>
#include <NRF24L01.h>
#include <MirfHardwarespiDriver.h>
int led = 14;
int i;
void setup() {
pinMode(led, OUTPUT);
Serial.begin(9600);
Mirf.spi=&MirfHardwareSpi;
Mirf.init();
Mirf.setRADDR((byte*)"clie1");
Mirf.setTADDR((byte*)"clie2");
Mirf.payload=sizeof(unsigned long);
Mirf.config();
byte rf_setup=0;
Mirf.readRegister(RF_SETUP , &rf_setup,sizeof(rf_setup));
if(rf_setup!=0)
Serial.println("beginning");
else
{Serial.println("no signal");
while(rf_setup=0);}
delay(1000);
}
void loop() {
while(!Mirf.dataReady())
{
Mirf.getData((byte *) &i);
digitalWrite(led, HIGH);
}
}
اما هیچ جوابی نمیگیرم . به محض اتصال برد دوم به تغذیه LED متصل به پایه 14 برد دوم روشن میشه و روشن میمونه
اگه کسی در این مورد میدونه لطفا بگه من چه کار کنم؟؟؟؟؟؟؟؟؟؟

**mohsen.mgha** · 06-29-2015, 04:11 PM

دوستان من هم به مشکلی شبیه به دوستمون برخودم که اطلاعات چهار بایتی دریافت میشن
با توجه به اینکه طول داده را در هر دو برد 16 تعریف کردم ولی در سمت گیرنده اطلاعات به اندازه ه چها بایت اول داده ارسالی دریافت و به اندازه ی طول داده ی ارسالی؛اون چهار بایت اول کپی میشن در ارایه ی دریافتی
مثلا اگه ارسال کنم: "mohammad"
این دریافت میشه: "mohamoha"

**magmagmary** · 06-30-2015, 08:58 AM

دوست من شما هم به فروم nrf سر بزنید و از اون کداستفاده کنید

**mohammad_robotic** · 07-02-2015, 10:01 AM

من عینا از کد اول فروم استفاده کردم

ولی

**amir321** · 07-27-2015, 05:54 PM

نوشته اصلی توسط e.rasekh

ماژول فرستنده و گيرنده راديويي +nRF24L01 از جديدترين فرستنده و گيرنده 2.4 گيگاهرتزي شركت Nordic Semiconductor يعني چيپ +nRF24L01 استفاده مي كند. فركانس اين آي سي براي دريافت و ارسال راديويي اطلاعات باند 2.4 گيگاهرتز بوده و مشخصات بسيار جديدي دارد. اين آي سي تمامي مشخصات و مزاياي آي سي سري قبل خود يعني nRF24L01A را داراست. بعلاوه pipeline و بافرهاي اضافي، و همچنين ارسال مجدد اتوماتيك، از قابليتهاي اضافه شده در اين سري از آي سي هاي RF است.

توجه: در سري پلاس «+» از اين آي سي ها يعني +nRF24L01 شركت Nordic مشخصاتي مانند برد، حساسيت و نرخ تبادل اطلاعات را نسبت به محصول سري قبل يعني nRF24L01 ارتقاء داده است. با اين حال دستورات كنترلي يا Command های اين سري با سري قبل يكي بوده و تغييري نداشته است.

مشخصات:

آنتن 2.4 گيگاهرتز روي بورد
برد 100 متر
نرخ تبادل اطلاعات قابل تنظيم از 250 كيلوبيت تا 2 مگابيت بر ثانيه
Auto Acknowledge
Re-Transmit Auto
Multiceiver با 6 ديتاپايپ
داراي 32 بايت FIFO بصورت مجزا براي TX و RX
پايه هاي ورودي با تحمل ولتاژ 5 ولت
قابليت تنظيم كانال ارتباطي از 2400 مگاهرتز تا 2525 مگاهرتز (125كانال قابل انتخاب)
حداقل نياز به قطعات جانبي جهت راه اندازي
ترتيب پايه ها :VCC ، CE ، CSN ، SCK ، MOSI ، MISO ، IRQ

شماتیک مدار:

برای دیدن سایز بزرگ روی عکس کلیک کنید

نام: NRF24L01_SCH.jpg
مشاهده: 2891
حجم: 86.0 کیلو بایت

مثال آردوینو:

کد:

/*
 # Be name Khoda!
 # A Mirf example to test the latency between two Ardunio.

 # Company    : AftabRayaneh
 # Website    : http://shop.aftabrayaneh.com
 # Developers : Reza Najafi, Elham Rasekh
 # Date       : 09.09.2013
 # Version    : 3.0
 
 * Pins:
 * Hardware SPI:
 * MISO -> 12
 * MOSI -> 11
 * SCK -> 13
 *
 * Configurable:
 * CE -> 8
 * CSN -> 7
 */

#include <SPI.h>
#include <Mirf.h>
#include <nRF24L01.h>
#include <MirfHardwareSpiDriver.h>

const int MAX_BUFFER_LEN = 16;
String Receive_Address = "clie1"; //A name that is dedicated to this station; MAX is 5 Char.
String Send_Address = "clie2";    //A name that is dedicated to another station; MAX is 5 Char. 

String strMirfBuffer="";
byte Transfer_Lock=0;

void setup()
{  
  Serial.begin(9600); 
  Setup_Mirf(); // initializing overall needed...  
  sendData("TALK"); 
}

void loop()
{
  if (!Mirf.isSending())
     check_MirfBuffer();  
  read_SerialBuffer();
} 

//This function checks mirf data availability. if data is available, put it in the buffer and generates an event.
void check_MirfBuffer()
{
  if (Mirf.dataReady())
  { 
    while(Mirf.dataReady())
    {
      int  tmp_index=0;
      byte tmp_buffer[4]={0};
      Mirf.getData(tmp_buffer);  
      while(tmp_buffer[tmp_index] && tmp_index<4 )
      {
        strMirfBuffer = strMirfBuffer + char(tmp_buffer[tmp_index]);
        tmp_index++;
      }
      if (strMirfBuffer.length() >= MAX_BUFFER_LEN ) 
        buffer_ready();     
     
      if (!Mirf.dataReady())
        delay(2);     
    }
  }
  else if (strMirfBuffer.length()>0 )   
    buffer_ready();   
}

//This function sends a 4 byte packet
void sendPacket(char packet[5])
{   
  Mirf.send((byte *)packet);
  while(Mirf.isSending());
}

//This function sends data 
void sendData(String strData)
{
  int StrLen=0;
  String tmp_Str="";
  Serial.print("sending data: ");
  Serial.print(strData);
  Transfer_Lock=1;
  StrLen=strData.length();
  Serial.print(" : ");
  Serial.println(StrLen);
  
  //parsing the data to 4 character packets (byte *)packet
  while (StrLen>0)
  {
    char tmp_Char[5]={0};
    if(StrLen>4)
    {
      tmp_Str=strData.substring(0,4);
      strData=strData.substring(4);
    }
    else
    {
      tmp_Str=strData;
      strData="";
    }
    tmp_Str.toCharArray(tmp_Char, 5);;
    sendPacket(tmp_Char); 
    StrLen=strData.length();    
  }  
  Transfer_Lock=0;
}

//This function parses received commands from another nrfs.
void buffer_ready()
{  
  if (strMirfBuffer == "TALK")
  {
    sendData("HURRAY !");
    Serial.println("Talking...");  
  }   
  //and parse other commands so on ...
  else 
  {
    Serial.print("<");
    Serial.print(strMirfBuffer);
    Serial.println(">");
  }
  clear_buffer(); 
}

//This function forms a buffer of serial data and send it
void read_SerialBuffer()
{
  if(Serial.available())
  {
    char CharData;
    String StrSerialBuffer=""; 
    
    while (Serial.available() && StrSerialBuffer.length() < MAX_BUFFER_LEN ) 
    {      
      CharData=Serial.read();
      StrSerialBuffer=StrSerialBuffer + CharData;   
      if (!Serial.available())
         delay(1);       
    }      
     while (Transfer_Lock); //wait for transfer process     
      
     sendData(StrSerialBuffer);    
  }
}

//This function initializes overall needed for wireless communication
void Setup_Mirf() 
{
  char Receive_Adr_Char[6];
  char Send_Adr_Char[6];
  Receive_Address.toCharArray(Receive_Adr_Char, 6); 
  Send_Address.toCharArray(Send_Adr_Char, 6); 

  Mirf.spi = &MirfHardwareSpi;
  Mirf.init();
  Mirf.setRADDR((byte *)Receive_Adr_Char);
  Mirf.setTADDR((byte *)Send_Adr_Char);
  Mirf.payload = sizeof(unsigned long);
  Mirf.config();

  //reg - Start  
  byte rf_setup = 0;
  Mirf.readRegister( RF_SETUP, &rf_setup, sizeof(rf_setup) );

  if (rf_setup != 0)   
    Serial.println("Beginning ... "); 
  else
  {
    Serial.println( "Wireless did not initialize!" );
    while (rf_setup==0);       
  }
  delay(100);
}

//This function clears the buffer
void clear_buffer ()
{
  strMirfBuffer="";
}

جهت سفارش این کالا، به این بخش در فروشگاه آفتاب رایانه مراجعه نمایید.

وظیفه هر پایه چیه وباید به کجا وصل بشه؟

**magmagmary** · 08-01-2015, 05:21 AM

دوسن من این ماژول ها 3.3 هستند شما که به 5 وصل نکردید انشاءالله

**مهد** · 09-09-2015, 02:18 PM

سلام
ببخش بردم اگر 5 باشه چطور 3.3 کنم

موضوع: ماژول انتقال بیسیم اطلاعات +nrf24l01 ( فرکانس 2.4g ) + آنتن

LinkBack

ابزارهای موضوع

جستجو موضوع

نحوه نمایش موضوع

Hybrid View

مجوز های ارسال و ویرایش